source: gcompris-qt/trunk/fuentes/CMakeLists.txt @ 4951

Last change on this file since 4951 was 4951, checked in by mabarracus, 4 years ago

Initial import gcompris-qt from git

File size: 17.4 KB
Line 
1if(SAILFISHOS)
2  cmake_minimum_required(VERSION 2.8.11)
3else(SAILFISHOS)
4  cmake_minimum_required(VERSION 2.8.12)
5endif()
6
7project(gcompris-qt C CXX)
8
9# get all the redist dll needed for windows when compiling with vc
10set(CMAKE_INSTALL_UCRT_LIBRARIES 1)
11include(InstallRequiredSystemLibraries)
12
13# Set c++11 support
14include(CheckCXXCompilerFlag)
15CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
16CHECK_CXX_COMPILER_FLAG("-std=c++0x" COMPILER_SUPPORTS_CXX0X)
17if(COMPILER_SUPPORTS_CXX11)
18        set(my_cxx_flags "-std=c++11")
19elseif(COMPILER_SUPPORTS_CXX0X)
20        set(my_cxx_flags "-std=c++0x")
21else()
22        message(STATUS "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
23endif()
24
25set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${my_cxx_flags}")
26set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${my_cxx_flags}")
27
28# enable qml debugging for DEBUG builds:
29set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DQT_QML_DEBUG")
30
31set(GCOMPRIS_MAJOR_VERSION 0)
32set(GCOMPRIS_MINOR_VERSION 70)
33set(GCOMPRIS_PATCH_VERSION 0)
34
35# Set the BUILD_DATE
36string(TIMESTAMP BUILD_DATE %Y%M)
37
38# cmake modules setup
39find_package(ECM 1.4.0 QUIET NO_MODULE)
40set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${ECM_KDE_MODULE_DIR} ${CMAKE_SOURCE_DIR}/cmake/)
41set(CMAKE_PREFIX_PATH "${Qt5_DIR}/lib/cmake/Qt5")
42
43# KDE po to qm tools
44if(ECM_FOUND)
45  include(ECMPoQmTools)
46  if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/po")
47    ecm_install_po_files_as_qm(po)
48  endif()
49endif(ECM_FOUND)
50
51if(CMAKE_SYSTEM_NAME STREQUAL Android)
52  find_package(ECM)
53  set(ANDROID 1)
54  # TODO: possibly should be setup by toolchain one day
55  set(QT_QMAKE_EXECUTABLE "${_qt5Core_install_prefix}/bin/qmake")
56  # workaround until this fix is in released ECM
57  if(ECM_VERSION VERSION_LESS "5.15.0")
58    add_definitions(-DANDROID)
59  endif()
60endif()
61
62# Set executable filename
63if(ANDROID)
64  set(GCOMPRIS_EXECUTABLE_NAME GCompris)
65  if("${ANDROID_ARCHITECTURE}" STREQUAL "x86")
66    # We always want x86 to be a release above to arm one because the play
67    # store want x86 to be pushed after arm.
68    MATH(EXPR GCOMPRIS_MINOR_VERSION "${GCOMPRIS_MINOR_VERSION}+1")
69  endif("${ANDROID_ARCHITECTURE}" STREQUAL "x86")
70elseif(SAILFISHOS)
71  set(GCOMPRIS_EXECUTABLE_NAME harbour-gcompris-qt)
72elseif(WIN32)
73  set(GCOMPRIS_EXECUTABLE_NAME GCompris)
74else()
75  set(GCOMPRIS_EXECUTABLE_NAME gcompris-qt)
76endif()
77
78set(GCOMPRIS_VERSION ${GCOMPRIS_MAJOR_VERSION}.${GCOMPRIS_MINOR_VERSION})
79
80# An integer value that represents the version of the application
81# Increase it at each release
82math(EXPR GCOMPRIS_VERSION_CODE "${GCOMPRIS_MAJOR_VERSION}*10000 + ${GCOMPRIS_MINOR_VERSION}*100 + ${GCOMPRIS_PATCH_VERSION}")
83
84# KDE po to qm tools
85if(ECM_FOUND)
86  include(ECMPoQmTools)
87  if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/po")
88    ecm_install_po_files_as_qm(po)
89  endif()
90endif(ECM_FOUND)
91
92# prevent build in source directory
93if("${CMAKE_BINARY_DIR}" STREQUAL "${CMAKE_SOURCE_DIR}")
94    message(SEND_ERROR "Building in the source directory is not supported.")
95    message(FATAL_ERROR "Please remove the created \"CMakeCache.txt\" file, the \"CMakeFiles\"
96            directory and create a build directory and call \"${CMAKE_COMMAND} <path to the sources>\".")
97endif("${CMAKE_BINARY_DIR}" STREQUAL "${CMAKE_SOURCE_DIR}")
98
99# Sailfish does not provide a recent Qt version
100if(SAILFISHOS)
101  set(QT_REQUIRED_VERSION 5.2.2)
102else()
103  set(QT_REQUIRED_VERSION 5.3.0)
104endif()
105
106find_package(Qt5 ${QT_REQUIRED_VERSION} REQUIRED
107            Qml Quick Gui Multimedia Core Svg Xml XmlPatterns LinguistTools Sensors)
108
109find_package (KF5 QUIET COMPONENTS
110    DocTools
111)
112if(KF5_FOUND)
113    include(KDEInstallDirs)
114
115    if (ECM_VERSION VERSION_GREATER "1.6.0")
116        add_subdirectory(images)
117        install(FILES org.kde.gcompris.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
118        install(FILES org.kde.gcompris.desktop DESTINATION ${KDE_INSTALL_APPDIR})
119    endif()
120endif()
121
122FIND_PROGRAM(LRELEASE_EXECUTABLE lrelease-qt5 lrelease
123  PATHS
124  ${Qt5_DIR}/../../../bin/
125  /usr/local/bin
126  /usr/bin/
127  NO_DEFAULT_PATH
128)
129
130#get_cmake_property(_variableNames VARIABLES)
131#foreach (_variableName ${_variableNames})
132#    message("${_variableName}=${${_variableName}}")
133#endforeach()
134
135set(ACTIVATION_MODE "no" CACHE STRING "Policy for activation [no|inapp|internal]")
136option(WITH_DEMO_ONLY "Include only demo activities" OFF)
137
138option(WITH_DOWNLOAD "Internal download" ON)
139# @FIXME These permissions should be removed if download is disable
140#        but it makes the application crash on exit (tested on Android 6)
141set(ANDROID_INTERNET_PERMISSION "<uses-permission android:name=\"android.permission.INTERNET\" />")
142set(ANDROID_ACCESS_NETWORK_STATE_PERMISSION "<uses-permission android:name=\"android.permission.ACCESS_NETWORK_STATE\" />")
143
144# Set output directory
145if(CMAKE_HOST_APPLE)
146  set(_bundle_bin gcompris-qt.app/Contents/MacOS)
147  set(_data_dest_dir bin/${_bundle_bin}/../Resources)
148elseif(ANDROID)
149  set(_data_dest_dir android/assets)
150else()
151  set(_data_dest_dir share/${GCOMPRIS_EXECUTABLE_NAME})
152endif()
153if(ANDROID)
154  # Android .so output
155  set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/android/libs/${ANDROID_ABI}/)
156  set(GCOMPRIS_TRANSLATIONS_DIR ${CMAKE_BINARY_DIR}/${_data_dest_dir} CACHE INTERNAL "" FORCE)
157  set(GCOMPRIS_RCC_DIR ${CMAKE_BINARY_DIR}/${_data_dest_dir} CACHE INTERNAL "" FORCE)
158  if(ACTIVATION_MODE STREQUAL "inapp")
159    set(ANDROID_BILLING_PERMISSION "<uses-permission android:name=\"com.android.vending.BILLING\"/>")
160    set(ANDROID_PACKAGE "net.gcompris")
161  else(ACTIVATION_MODE)
162    set(ANDROID_PACKAGE "net.gcompris.full")
163  endif()
164  add_subdirectory(android)
165elseif(CMAKE_HOST_APPLE)
166  # MacOSX build
167  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
168  set(GCOMPRIS_TRANSLATIONS_DIR ${CMAKE_BINARY_DIR}/${_data_dest_dir}/translations CACHE INTERNAL "" FORCE)
169  set(GCOMPRIS_RCC_DIR ${CMAKE_BINARY_DIR}/${_data_dest_dir}/rcc CACHE INTERNAL "" FORCE)
170else()
171  # Desktop build
172  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
173  set(GCOMPRIS_TRANSLATIONS_DIR ${CMAKE_BINARY_DIR}/${_data_dest_dir}/translations CACHE INTERNAL "" FORCE)
174  set(GCOMPRIS_RCC_DIR ${CMAKE_BINARY_DIR}/${_data_dest_dir}/rcc CACHE INTERNAL "" FORCE)
175endif(ANDROID)
176
177# Always create these folders
178add_custom_command(
179  OUTPUT shareFolders
180  COMMAND cmake -E make_directory ${GCOMPRIS_TRANSLATIONS_DIR}
181  COMMAND cmake -E make_directory ${GCOMPRIS_RCC_DIR}
182  )
183add_custom_target(
184  createShareFolders ALL
185  DEPENDS shareFolders
186  )
187
188include(cmake/rcc.cmake)
189
190# Translations handling
191
192# Simple command calling the python script
193  add_custom_command(
194    OUTPUT retrievePoFilesFromSvn
195    COMMAND python2 tools/l10n-fetch-po-files.py
196    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
197    )
198# Install translations
199add_custom_target(getSvnTranslations
200  DEPENDS retrievePoFilesFromSvn
201  COMMENT "Re-run cmake after this to be able to run BuildTranslations with the latest files"
202  )
203
204# Get all po files in po/. You can get them doing: python2 tools/l10n-fetch-po-files.py
205file(GLOB TRANSLATIONS_FILES RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "po/*.po")
206# Set the output dir for the translation files to /bin
207foreach(PoSource ${TRANSLATIONS_FILES})
208  # Changes the .po extension to .ts
209  string(REPLACE ".po" ".ts" TsSource ${PoSource})
210  # Removes the po/ folder
211  string(REPLACE "po/" "" TsSource ${TsSource})
212  # qm filename
213  string(REPLACE ".ts" ".qm" QmOutput ${TsSource})
214
215  set(OutTsFile ${CMAKE_BINARY_DIR}/tmp/${TsSource})
216  add_custom_command(
217    OUTPUT ${QmOutput}
218    COMMAND cmake -E make_directory ${GCOMPRIS_TRANSLATIONS_DIR}
219    COMMAND cmake -E make_directory ${CMAKE_BINARY_DIR}/tmp
220    # Remove the obsolete translations and set po in the ts output file
221    COMMAND msgattrib --no-obsolete  ${CMAKE_CURRENT_SOURCE_DIR}/${PoSource} -o ${OutTsFile}
222    # Convert the po into ts
223    COMMAND Qt5::lconvert -if po -of ts -i ${OutTsFile} -o ${OutTsFile}
224    # Convert the ts in qm removing non finished translations
225    COMMAND Qt5::lrelease -compress -nounfinished ${OutTsFile} -qm ${GCOMPRIS_TRANSLATIONS_DIR}/${QmOutput}
226    )
227  list(APPEND QM_FILES ${QmOutput})
228endforeach()
229
230# Install translations
231if (WIN32)
232    add_custom_target(BuildTranslations
233        DEPENDS ${QM_FILES}
234        COMMENT "If you don't have the .po, you need to run make getSvnTranslations first then re-run cmake"
235    )
236else()
237    add_custom_target(BuildTranslations ALL
238        DEPENDS ${QM_FILES}
239        COMMENT "If you don't have the .po, you need to run make getSvnTranslations first then re-run cmake"
240    )
241endif()
242
243add_custom_command(
244    OUTPUT doBundleTranslations
245    COMMAND 7z a -w${CMAKE_BINARY_DIR}/share/${GCOMPRIS_EXECUTABLE_NAME}
246               ${CMAKE_BINARY_DIR}/translations-${GCOMPRIS_VERSION}.7z
247               ${CMAKE_BINARY_DIR}/share/${GCOMPRIS_EXECUTABLE_NAME}/translations
248    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
249    )
250# Bundle translations
251add_custom_target(BundleTranslations
252  DEPENDS doBundleTranslations
253  COMMENT "If you want to provide a zip of the translations on a server (run make BuildTranslations first)"
254  )
255
256add_custom_command(
257    OUTPUT doDlAndInstallBundledTranslations
258    COMMAND curl -fsS -o translations-${GCOMPRIS_VERSION}.7z
259                 http://gcompris.net/download/translations-${GCOMPRIS_VERSION}.7z
260    COMMAND 7z x -y -o${CMAKE_BINARY_DIR}/share/${GCOMPRIS_EXECUTABLE_NAME}
261               translations-${GCOMPRIS_VERSION}.7z
262    WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
263    )
264# Download and install bundled translations
265add_custom_target(DlAndInstallBundledTranslations
266  DEPENDS doDlAndInstallBundledTranslations
267  COMMENT "Download the bundled translation and install them in the build dir"
268  )
269
270if(CMAKE_HOST_APPLE)
271  install(DIRECTORY ${GCOMPRIS_TRANSLATIONS_DIR} DESTINATION ${_bundle_bin})
272else()
273  install(DIRECTORY ${GCOMPRIS_TRANSLATIONS_DIR} DESTINATION ${_data_dest_dir})
274endif()
275
276# Build standalone package option -> if ON, we will copy the required Qt files in the build package.
277# If OFF, "make install" will not copy Qt files so only GCompris files will be packaged.
278# By default, it is true on Windows (as we deliver NSIS package), macOS (bundled), android (apk) and false on linux (to do make install)
279# If you want to create a STGZ package for linux (auto-extractible), override this variable by typing : cmake -DBUILD_STANDALONE=ON
280if(UNIX AND NOT ANDROID AND NOT APPLE)
281  option(BUILD_STANDALONE "Build a standalone package when typing 'make package'" OFF)
282else()
283  option(BUILD_STANDALONE "Build a standalone package when typing 'make package'" ON)
284endif()
285
286option(WITH_KIOSK_MODE "Set the kiosk mode by default" OFF)
287
288if(WIN32)
289  set(COMPRESSED_AUDIO "mp3" CACHE STRING "Compressed Audio format [ogg|aac|mp3]")
290elseif(APPLE)
291  set(COMPRESSED_AUDIO "aac" CACHE STRING "Compressed Audio format [ogg|aac|mp3]")
292else()
293  set(COMPRESSED_AUDIO "ogg" CACHE STRING "Compressed Audio format [ogg|aac|mp3]")
294endif()
295
296file(GLOB_RECURSE OGG_FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/ "*.ogg")
297
298foreach(OGG_FILE ${OGG_FILES})
299  # This should only replace the extension
300  string(REGEX REPLACE "ogg$" "aac" AAC_FILE ${OGG_FILE})
301  add_custom_command(
302    OUTPUT ${AAC_FILE}
303    # Put the good line depending on your installation
304    COMMAND avconv -v warning -i ${OGG_FILE} -acodec libvo_aacenc ${AAC_FILE}
305    #COMMAND ffmpeg -v warning -i ${OGG_FILE} -acodec aac -strict -2 ${AAC_FILE}
306    )
307  list(APPEND AAC_FILES ${AAC_FILE})
308
309  # This should only replace the extension
310  string(REGEX REPLACE "ogg$" "mp3" MP3_FILE ${OGG_FILE})
311  add_custom_command(
312    OUTPUT ${MP3_FILE}
313    # Put the good line depending on your installation
314    #COMMAND avconv -v warning -i ${OGG_FILE} -acodec mp3 ${MP3_FILE}
315    COMMAND ffmpeg -v warning -i ${OGG_FILE} -acodec mp3 -strict -2 ${MP3_FILE}
316    )
317  list(APPEND MP3_FILES ${MP3_FILE})
318endforeach()
319
320add_custom_target(
321  createAacFromOgg
322  DEPENDS ${AAC_FILES}
323  )
324
325add_custom_target(
326  createMp3FromOgg
327  DEPENDS ${MP3_FILES}
328  )
329
330# predownload assets (voices and images) and install them in the rcc folder
331set(DOWNLOAD_ASSETS "" CACHE STRING "Download and packages images and voices. use a list like: words,en,fr,pt_BR to retrieve multiple files")
332add_custom_command(
333    OUTPUT predownloadAssets
334    COMMAND python2 tools/download-assets.py ${DOWNLOAD_ASSETS} ${COMPRESSED_AUDIO} ${GCOMPRIS_RCC_DIR}
335    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
336    )
337
338add_custom_command(
339  OUTPUT assetsFolders
340  COMMAND cmake -E make_directory "${GCOMPRIS_RCC_DIR}/data2"
341  COMMAND cmake -E make_directory "${GCOMPRIS_RCC_DIR}/data2/voices-${COMPRESSED_AUDIO}"
342  COMMAND cmake -E make_directory "${GCOMPRIS_RCC_DIR}/data2/words"
343  )
344# Install assets
345add_custom_target(getAssets
346  DEPENDS assetsFolders predownloadAssets
347  )
348
349add_custom_command(
350    OUTPUT doBundleConvertedOggs
351    COMMAND 7z a converted_ogg_to_${COMPRESSED_AUDIO}-${GCOMPRIS_VERSION}.7z '-ir!src/*${COMPRESSED_AUDIO}'
352    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
353    )
354# Bundle oggs ready to be uploaded on a server. This ease build on system without the appropriate audio
355# convertion tools.
356add_custom_target(BundleConvertedOggs
357  DEPENDS doBundleConvertedOggs
358  COMMENT "Bundle the converted oggs to upload them on a server. First set COMPRESSED_AUDIO appropriately."
359  )
360
361add_custom_command(
362    OUTPUT doDlAndInstallBundledConvertedOggs
363    COMMAND curl -fsS -o converted_ogg_to_${COMPRESSED_AUDIO}-${GCOMPRIS_VERSION}.7z
364            http://gcompris.net/download/converted_ogg_to_${COMPRESSED_AUDIO}-${GCOMPRIS_VERSION}.7z
365    COMMAND 7z x -y converted_ogg_to_${COMPRESSED_AUDIO}-${GCOMPRIS_VERSION}.7z
366    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
367    )
368# Download and install bundled converted oggs
369add_custom_target(DlAndInstallBundledConvertedOggs
370  DEPENDS doDlAndInstallBundledConvertedOggs
371  COMMENT "Download the bundled converted oggs and install them in the source dir"
372  )
373
374
375set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${GCOMPRIS_VERSION})
376add_custom_target(dist
377    COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD
378        | xz > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.xz
379    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
380
381if(KF5_FOUND)
382    add_subdirectory(docs/docbook)
383endif(KF5_FOUND)
384
385if(SAILFISHOS)
386  # Need to be done at the end, after src
387  add_subdirectory(platforms/sailfishOS)
388endif()
389
390#
391# qml-box2d
392#
393
394set(QML_BOX2D_MODULE "auto" CACHE STRING "Policy for qml-box2d module [auto|submodule|system|disabled]")
395
396if (${QML_BOX2D_MODULE} STREQUAL "disabled")
397  # disable all activities depending on qml-box2d
398  set(_disabled_activities "balancebox,land_safe")
399  message(STATUS "Disabling qml-box2d module and depending activities: ${_disabled_activities}")
400else()
401  include(qt_helper)
402
403  getQtQmlPath(_qt_qml_system_path)
404  set (_box2d_system_dir "${_qt_qml_system_path}/Box2D.2.0")
405
406  if (${QML_BOX2D_MODULE} STREQUAL "submodule")
407    message(STATUS "Building qml-box2d module from submodule")
408    set(_need_box2d_submodule "TRUE")
409  else()
410    # try to find module in system scope
411    find_library(QML_BOX2D_LIBRARY NAMES Box2D libBox2D PATHS ${_box2d_system_dir} NO_DEFAULT_PATH)
412    if (QML_BOX2D_LIBRARY)
413      message(STATUS "Using system qml-box2d plugin at ${QML_BOX2D_LIBRARY}")
414      # for packaging builds, copy the module manually to the correct location
415      if(SAILFISHOS)
416        file(COPY ${_box2d_system_dir}/qmldir ${QML_BOX2D_LIBRARY} DESTINATION share/harbour-gcompris-qt/lib/qml/Box2D.2.0)
417      elseif(ANDROID)
418        file(COPY ${_box2d_system_dir}/qmldir ${QML_BOX2D_LIBRARY} DESTINATION lib/qml/Box2D.2.0)
419      endif()
420      # FIXME: add others as needed
421    else()
422      if (${QML_BOX2D_MODULE} STREQUAL "auto")
423        message(STATUS "Did not find the qml-box2d module in system scope, falling back to submodule build ...")
424        set (_need_box2d_submodule "TRUE")
425      else()
426        message(FATAL_ERROR "Did not find the qml-box2d module in system scope and submodule build was not requested. Can't continue!")
427      endif()
428    endif()
429  endif()
430
431  if (_need_box2d_submodule)
432    # build qml-box2d ourselves from submodule
433    include(ExternalProject)
434    get_property(_qmake_program TARGET ${Qt5Core_QMAKE_EXECUTABLE} PROPERTY IMPORT_LOCATION)
435    set (_box2d_source_dir ${CMAKE_CURRENT_SOURCE_DIR}/external/qml-box2d)
436    if(WIN32)
437      set (_box2d_library_dir "release/")
438      set (_box2d_library_file "Box2D.dll")
439    else()
440      set (_box2d_library_dir "")
441      set (_box2d_library_file "libBox2D.so")
442    endif()
443    set (_box2d_install_dir ${CMAKE_CURRENT_BINARY_DIR}/lib/qml/Box2D.2.0)
444    # make sure submodule is up2date
445    find_package(Git)
446    if(GIT_FOUND)
447      execute_process(COMMAND ${GIT_EXECUTABLE} submodule update --init)
448    endif()
449
450    # for visual studio, we need to create a vcxproj
451    if(WIN32 AND NOT MINGW)
452      set(_qmake_options -spec win32-msvc2015 -tp vc)
453    else()
454      set(_qmake_options "")
455    endif()
456    ExternalProject_Add(qml_box2d
457      DOWNLOAD_COMMAND ""
458      SOURCE_DIR ${_box2d_source_dir}
459      CONFIGURE_COMMAND ${_qmake_program} ${_qmake_options} ${_box2d_source_dir}/box2d.pro
460      BUILD_COMMAND ${CMAKE_MAKE_PROGRAM}
461      INSTALL_DIR ${_box2d_install_dir}
462      INSTALL_COMMAND cp ${_box2d_library_dir}${_box2d_library_file} ${_box2d_source_dir}/qmldir ${_box2d_install_dir}
463      )
464
465    add_library(qml-box2d SHARED IMPORTED)
466    set_target_properties(qml-box2d PROPERTIES IMPORTED_LOCATION ${_box2d_install_dir}/${_box2d_library_file})
467
468    if(SAILFISHOS)
469      install(DIRECTORY ${_box2d_install_dir} DESTINATION share/harbour-gcompris-qt/lib/qml)
470    else()
471      install(DIRECTORY ${_box2d_install_dir} DESTINATION lib/qml)
472    endif()
473  endif()
474endif()
475
476add_subdirectory(src)
477
478add_custom_target(binaries)
479add_dependencies(binaries ${GCOMPRIS_EXECUTABLE_NAME} rcc_core rcc_menu rcc_activities all_activities)
Note: See TracBrowser for help on using the repository browser.