source: ocsinventory-agent/trunk/fuentes/lib/Ocsinventory/Agent/Backend/OS/Generic/Screen.pm @ 468

Last change on this file since 468 was 468, checked in by mabarracus, 4 years ago

Copyt trusty code

File size: 19.9 KB
Line 
1package Ocsinventory::Agent::Backend::OS::Generic::Screen;
2#     Copyright (C) 2005 Mandriva
3#     Copyright (C) 2007 Gonéri Le Bouder <goneri@rulezlan.org>
4#     This program is free software; you can redistribute it and/or modify
5#     it under the terms of the GNU General Public License as published by
6#     the Free Software Foundation; either version 2 of the License, or
7#     (at your option) any later version.
8
9#     This program is distributed in the hope that it will be useful,
10#     but WITHOUT ANY WARRANTY; without even the implied warranty of
11#     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
12#     GNU General Public License for more details.
13
14#     You should have received a copy of the GNU General Public License
15#     along with this program; if not, write to the Free Software
16#     Foundation (website: http://www.fsf.org).
17#
18# Some part come from Mandriva's (great) monitor-edid
19# http://svn.mandriva.com/cgi-bin/viewvc.cgi/soft/monitor-edid/trunk/
20#
21use strict;
22
23sub check {
24
25  return unless (can_run("monitor-get-edid-using-vbe") || can_run("monitor-get-edid") || can_run("get-edid"));
26 
27  1;
28}
29
30sub getEdid {
31  my $raw_edid;
32
33# Mandriva
34  $raw_edid = `monitor-get-edid-using-vbe 2>/dev/null`;
35
36  # Since monitor-edid 1.15, it's possible to retrieve EDID information
37  # through DVI link but we need to use monitor-get-edid
38  if (!$raw_edid) {
39      $raw_edid = `monitor-get-edid 2>/dev/null`;
40  }
41
42  if (!$raw_edid) {
43    foreach (1..5) { # Sometime get-edid return an empty string...
44      $raw_edid = `get-edid 2>/dev/null`;
45      last if (length($raw_edid) == 128 || length($raw_edid) == 256);
46    }
47  }
48  return unless (length($raw_edid) == 128 || length($raw_edid) == 256);
49
50  return $raw_edid;
51}
52
53my @CVT_ratios = qw(5/4 4/3 3/2 16/10 15/9 16/9);
54my @known_ratios = @CVT_ratios;
55
56my @edid_info = group_by2(
57  a8 => '_header',
58  a2  => 'manufacturer_name',
59
60  v => 'product_code',
61  V => 'serial_number',
62  C => 'week',
63  C => 'year',
64  C => 'edid_version',
65  C => 'edid_revision',
66  a => 'video_input_definition',
67
68  C => 'max_size_horizontal', # in cm, 0 on projectors
69  C => 'max_size_vertical', # in cm, 0 on projectors
70  C => 'gamma',
71  a => 'feature_support',
72  a10 => '_color_characteristics',
73  a3  => 'established_timings',
74  a16 => 'standard_timings',
75  a72 => 'monitor_details',
76
77  C => 'extension_flag',
78  C => 'checksum',
79);
80
81my %subfields = (
82  manufacturer_name => [ group_by2(
83    1 => '',
84    5 => '1',
85    5 => '2',
86    5 => '3',
87  ) ],
88
89  video_input_definition => [ group_by2(
90    1 => 'digital',
91    1 => 'separate_sync',
92    1 => 'composite_sync',
93    1 => 'sync_on_green',
94    2 => '',
95    2 => 'voltage_level',
96  ) ],
97
98  feature_support => [ group_by2(
99    1 => 'DPMS_standby',
100    1 => 'DPMS_suspend',
101    1 => 'DPMS_active_off',       
102    1 => 'rgb',
103
104    1 => '',
105    1 => 'sRGB_compliance',
106    1 => 'has_preferred_timing',
107    1 => 'GTF_compliance',
108  ) ],
109
110  established_timings => [ group_by2(
111    1 => '720x400_70',
112    1 => '720x400_88',
113    1 => '640x480_60',
114    1 => '640x480_67',
115    1 => '640x480_72',
116    1 => '640x480_75',
117    1 => '800x600_56',
118    1 => '800x600_60',
119    1 => '800x600_72',
120    1 => '800x600_75',
121    1 => '832x624_75',
122    1 => '1024x768_87i',
123    1 => '1024x768_60',
124    1 => '1024x768_70',
125    1 => '1024x768_75',
126    1 => '1280x1024_75',
127  ) ],
128
129  detailed_timing => [ group_by2(
130    8 => 'horizontal_active',
131    8 => 'horizontal_blanking',
132    4 => 'horizontal_active_hi',
133    4 => 'horizontal_blanking_hi',
134    8 => 'vertical_active',
135    8 => 'vertical_blanking',
136    4 => 'vertical_active_hi',
137    4 => 'vertical_blanking_hi',
138    8 => 'horizontal_sync_offset',
139    8 => 'horizontal_sync_pulse_width',
140    4 => 'vertical_sync_offset',
141    4 => 'vertical_sync_pulse_width',
142    2 => 'horizontal_sync_offset_hi',
143    2 => 'horizontal_sync_pulse_width_hi',
144    2 => 'vertical_sync_offset_hi',
145    2 => 'vertical_sync_pulse_width_hi',
146    8 => 'horizontal_image_size', # in mm
147    8 => 'vertical_image_size', # in mm
148    4 => 'horizontal_image_size_hi',
149    4 => 'vertical_image_size_hi',
150    8 => 'horizontal_border',
151    8 => 'vertical_border',
152
153    1 => 'interlaced',
154    2 => 'stereo',     
155    2 => 'digital_composite',
156    1 => 'horizontal_sync_positive',
157    1 => 'vertical_sync_positive',
158    1 => '',
159  ) ],
160
161  standard_timing => [ group_by2(
162    8 => 'X',
163    2 => 'aspect',
164    6 => 'vfreq',
165  ) ],
166  monitor_range => [ group_by2(
167    8 => 'vertical_min',
168    8 => 'vertical_max',
169    8 => 'horizontal_min',
170    8 => 'horizontal_max',
171    8 => 'pixel_clock_max',
172  ) ],
173
174  manufacturer_specified_range_timing => [ group_by2(
175    # http://www.spwg.org/salisbury_march_19_2002.pdf
176    # for the glossary: http://www.vesa.org/Public/PSWG/PSWG15v1.pdf
177    8 => 'horizontal_sync_pulse_width_min', # HSPW (Horizontal Sync Pulse Width)
178    8 => 'horizontal_sync_pulse_width_max',
179    8 => 'horizontal_back_porch_min', # t_hbp
180    8 => 'horizontal_back_porch_max',
181    8 => 'vertical_sync_pulse_width_min', # VSPW (Vertical Sync Pulse Width)
182    8 => 'vertical_sync_pulse_width_max',
183    8 => 'vertical_back_porch_min', # t_vbp (Vertical Back Porch)
184    8 => 'vertical_back_porch_max',
185    8 => 'horizontal_blanking_min', # t_hp (Horizontal Period)
186    8 => 'horizontal_blanking_max',
187    8 => 'vertical_blanking_min', # t_vp
188    8 => 'vertical_blanking_max',
189    8 => 'module_revision',
190  ) ],
191);
192
193sub get_many_bits {
194  my ($s, $field_name) = @_;
195  my @bits = split('', unpack('B*', $s));
196  my %h;
197  foreach (@{$subfields{$field_name}}) {
198    my ($size, $field) = @$_;
199    my @l = ('0' x (8 - $size), splice(@bits, 0, $size));
200    $h{$field} = unpack("C", pack('B*', join('', @l))) if $field && $field !~ /^_/;
201  }
202  \%h;
203}
204
205sub check_parsed_edid {
206  my ($edid) = @_;
207
208  $edid->{manufacturer_name} ne '@@@' or return 'bad manufacturer_name';
209  $edid->{edid_version} != 0xff && $edid->{edid_revision} != 0xff or return 'bad edid_version';
210
211  if ($edid->{monitor_range}) {
212    $edid->{monitor_range}{horizontal_min} && 
213    $edid->{monitor_range}{horizontal_min} <= $edid->{monitor_range}{horizontal_max} 
214      or return 'bad HorizSync';
215    $edid->{monitor_range}{vertical_min} &&
216    $edid->{monitor_range}{vertical_min} <= $edid->{monitor_range}{vertical_max} 
217      or return 'bad VertRefresh';
218  }
219
220  '';
221}
222
223sub parse_edid {
224  my ($raw_edid) = @_;
225
226  my %edid;
227  my @vals = unpack(join('', map { $_->[0] } @edid_info), $raw_edid);
228  my $i;
229  foreach (@edid_info) {
230    my ($field, $v) = ($_->[1], $vals[$i++]);
231
232    if ($field eq 'year') {
233      $v += 1990;
234    } elsif ($field eq 'manufacturer_name') {
235      my $h = get_many_bits($v, 'manufacturer_name');
236      $v = join('', map { chr(ord('A') + $h->{$_} - 1) } 1 .. 3);
237    } elsif ($field eq 'video_input_definition') {
238      $v = get_many_bits($v, 'video_input_definition');
239    } elsif ($field eq 'feature_support') {
240      $v = get_many_bits($v, 'feature_support');
241    } elsif ($field eq 'established_timings') {
242      my $h = get_many_bits($v, 'established_timings');
243      $v = [
244      sort { $a->{X} <=> $b->{X} || $a->{vfreq} <=> $b->{vfreq} }
245      map { /(\d+)x(\d+)_(\d+)(i?)/ ? { X => $1, Y => $2, vfreq => $3, $4 ? (interlace => 1) : () } : () }
246      grep { $h->{$_} } keys %$h ];
247    } elsif ($field eq 'standard_timings') {
248      my @aspect2ratio = (
249        $edid{edid_version} > 1 || $edid{edid_revision} > 2 ? '16/10' : '1/1',
250        '4/3', '5/4', '16/9',
251      );
252      $v = [ map {
253        my $h = get_many_bits($_, 'standard_timing');
254        $h->{X} = ($h->{X} + 31) * 8;
255        if ($_ ne "\x20\x20" && $h->{X} > 256) { # cf VALID_TIMING in Xorg edid.h
256          $h->{vfreq} += 60;
257          if ($h->{ratio} = $aspect2ratio[$h->{aspect}]) {
258            delete $h->{aspect};
259            $h->{Y} = $h->{X} / eval($h->{ratio});
260          }
261          $h;
262        } else { () }
263      } unpack('a2' x 8, $v) ];
264    } elsif ($field eq 'monitor_details') {
265      while ($v) {
266        (my $pixel_clock, my $vv, $v) = unpack("v a16 a*", $v);
267
268        if ($pixel_clock) {
269          # detailed timing
270          my $h = get_many_bits($vv, 'detailed_timing');
271          $h->{pixel_clock} = $pixel_clock / 100; # to have it in MHz
272
273          my %detailed_timing_field_size = map { $_->[1], $_->[0] } @{$subfields{detailed_timing}};
274          foreach my $field (keys %detailed_timing_field_size) {
275            $field =~ s/_hi$// or next;
276            my $hi = delete($h->{$field . '_hi'});
277            $h->{$field} += $hi << $detailed_timing_field_size{$field};
278          }
279          push @{$edid{detailed_timings}}, $h
280          if $h->{horizontal_active} > 0 && $h->{vertical_active} > 0;
281        } else {
282          (my $flag, $vv) = unpack("n x a*", $vv);
283
284          if ($flag == 0xfd) {
285            # range
286            $edid{monitor_range} = get_many_bits($vv, 'monitor_range');
287            if ($edid{monitor_range}{pixel_clock_max} == 0xff) {
288              delete $edid{monitor_range}{pixel_clock_max};
289            } else {
290              $edid{monitor_range}{pixel_clock_max} *= 10; #- to have it in MHz
291            }
292          } elsif ($flag == 0xf) {
293            my $range = get_many_bits($vv, 'manufacturer_specified_range_timing');
294
295            my $e = $edid{detailed_timings}[0];
296            my $valid = 1;
297            foreach my $m ('min', 'max') {
298              my %total;
299              foreach my $dir ('horizontal', 'vertical') {
300                $range->{$dir . '_sync_pulse_width_' . $m} *= 2;
301                $range->{$dir . '_back_porch_' . $m} *= 2;
302                $range->{$dir . '_blanking_' . $m} *= 2;
303                if ($e && $e->{$dir . '_active'}) {
304                  $total{$dir} = $e->{$dir . '_active'} + $range->{$dir . '_blanking_' . $m};
305                }
306              }
307              if ($total{horizontal} && $total{vertical}) {
308                my $hfreq = $e->{pixel_clock} * 1000 / $total{horizontal};
309                my $vfreq = $hfreq * 1000 / $total{vertical};
310                $range->{'horizontal_' . ($m eq 'min' ? 'max' : 'min')} = round($hfreq);
311                $range->{'vertical_' . ($m eq 'min' ? 'max' : 'min')} = round($vfreq);
312              } else {
313                $valid = 0;
314              }
315            }
316            $edid{$valid ? 'monitor_range' : 'manufacturer_specified_range_timing'} = $range;
317
318          } elsif ($flag == 0xfc) {
319            my $prev = $edid{monitor_name};
320            $edid{monitor_name} = ($prev ? "$prev " : '') . unpack('A13', $vv);
321          } elsif ($flag == 0xfe) {
322            push @{$edid{monitor_text}}, unpack('A13', $vv);
323          } elsif ($flag == 0xff) {
324            push @{$edid{serial_number2}}, unpack('A13', $vv);
325          } else {
326            #warn "parse_edid: unknown flag $flag\n";
327          }
328        }
329      }
330    }
331
332    $edid{$field} = $v if $field && $field !~ /^_/;
333  }
334
335  $edid{max_size_precision} = 'cm';
336  $edid{EISA_ID} = $edid{manufacturer_name} . sprintf('%04x', $edid{product_code}) if $edid{product_code};
337
338  if ($edid{monitor_range}) {
339    $edid{HorizSync} = $edid{monitor_range}{horizontal_min} . '-' . $edid{monitor_range}{horizontal_max};
340    $edid{VertRefresh} = $edid{monitor_range}{vertical_min} . '-' . $edid{monitor_range}{vertical_max};
341  }
342
343  if ($edid{max_size_vertical}) {
344    $edid{ratio} = $edid{max_size_horizontal} / $edid{max_size_vertical};
345    $edid{ratio_name} = ratio_name($edid{max_size_horizontal}, $edid{max_size_vertical}, 'cm');
346    $edid{ratio_precision} = 'cm';
347  }
348
349  foreach my $h (@{$edid{detailed_timings}}) {
350    my $horizontal_total = $h->{horizontal_active} + $h->{horizontal_blanking};
351    my $vertical_total = $h->{vertical_active} + $h->{vertical_blanking};
352
353    $h->{ModeLine_comment} = sprintf qq(# Monitor preferred modeline (%.1f Hz vsync, %.1f kHz hsync, ratio %s)),
354  $h->{pixel_clock} / $horizontal_total / $vertical_total * 1000 * 1000,
355  $h->{pixel_clock} / $horizontal_total * 1000,
356  nearest_ratio($h->{horizontal_active} / $h->{vertical_active}, 0.01) || sprintf("%.2f", $h->{horizontal_active} / $h->{vertical_active});
357
358  $h->{ModeLine} = sprintf qq("%dx%d" $h->{pixel_clock} %d %d %d %d %d %d %d %d %shsync %svsync),
359  $h->{horizontal_active}, $h->{vertical_active},
360
361  $h->{horizontal_active},
362  $h->{horizontal_active} + $h->{horizontal_sync_offset}, 
363  $h->{horizontal_active} + $h->{horizontal_sync_offset} + $h->{horizontal_sync_pulse_width},
364  $horizontal_total,
365
366  $h->{vertical_active},
367  $h->{vertical_active} + $h->{vertical_sync_offset}, 
368  $h->{vertical_active} + $h->{vertical_sync_offset} + $h->{vertical_sync_pulse_width},
369  $vertical_total,
370
371  $h->{horizontal_sync_positive} ? '+' : '-',
372  $h->{vertical_sync_positive} ? '+' : '-';
373
374  # if the mm size given in the detailed_timing is not far from the cm size
375  # put it as a more precise cm size
376  my %in_cm = map { $_ => $h->{$_ . '_image_size'} / 10 } ('horizontal', 'vertical');
377  my ($error) = sort { $b <=> $a } map { abs($edid{'max_size_' . $_} - $in_cm{$_}) } keys %in_cm;
378  if ($error <= 0.5) {
379    $edid{'max_size_' . $_} = $in_cm{$_} foreach keys %in_cm;
380    $edid{max_size_precision} = 'mm';
381  }
382  if ($error < 1 && $in_cm{vertical}) {
383    # using it for the ratio
384    $edid{ratio} = $in_cm{horizontal} / $in_cm{vertical};
385    $edid{ratio_name} = ratio_name($in_cm{horizontal}, $in_cm{vertical}, 'mm');
386    $edid{ratio_precision} = 'mm';
387  }
388
389  $h->{bad_ratio} = 1 if abs($edid{ratio} - $h->{horizontal_active} / $h->{vertical_active}) > ($edid{ratio_precision} eq 'mm' ? 0.02 : 0.2);
390}
391
392$edid{diagonal_size} = sqrt(sqr($edid{max_size_horizontal}) + 
393  sqr($edid{max_size_vertical})) / 2.54;
394
395\%edid;
396}
397
398sub nearest_ratio {
399  my ($ratio, $max_error) = @_;
400  my @sorted = 
401  sort { $a->[1] <=> $b->[1] }
402  map { 
403    my $error = abs($ratio - eval($_));
404    $error > $max_error ? () : [ $_, $error ];
405  } @known_ratios;
406  $sorted[0][0];
407}
408
409sub ratio_name {
410  my ($horizontal, $vertical, $precision) = @_;
411
412  if ($precision eq 'mm') {
413    nearest_ratio($horizontal / $vertical, 0.1);
414  } else {
415    my $error = 0.5;
416    my $ratio1 = nearest_ratio(($horizontal + $error) / ($vertical - $error), 0.2);
417    my $ratio2 = nearest_ratio(($horizontal - $error) / ($vertical + $error), 0.2);
418    $ratio1 && $ratio2 or return;
419    if ($ratio1 eq $ratio2) {
420      $ratio1;
421    } else {
422      my $ratio = nearest_ratio($horizontal / $vertical, 0.2);
423      join(' or ', $ratio, $ratio eq $ratio1 ? $ratio2 : $ratio1);
424    }
425  }
426}
427
428sub to_MonitorsDB {
429  my ($edid) = @_;
430
431  $edid->{monitor_range} && $edid->{EISA_ID} or return;
432
433  my $detailed_timings = $edid->{detailed_timings} || [];
434  my @preferred_resolutions = map { 
435    join('x', $_->{horizontal_active}, $_->{vertical_active});
436  } grep { !$_->{bad_ratio} } @$detailed_timings;
437
438  (my $monitor_name = $edid->{monitor_name}) =~ s/;/,/g;
439  my ($raw_vendor, $raw_model) = $edid->{EISA_ID} =~ /(...)(.*)/;
440  my ($VendorName, $only_Model) =
441  $monitor_name =~ /(\S+)\s(.*)/ ? 
442  ($1, $2) :
443  ($raw_vendor, $monitor_name || $raw_model);
444
445  join('; ', 
446    $VendorName, "$VendorName $only_Model", $edid->{EISA_ID},
447    sprintf("%u-%u", $edid->{monitor_range}{horizontal_min}, $edid->{monitor_range}{horizontal_max}),
448    sprintf("%u-%u", $edid->{monitor_range}{vertical_min}, $edid->{monitor_range}{vertical_max}),
449    @$detailed_timings == 1 ? @preferred_resolutions : (),
450  );
451}
452
453sub print_edid {
454  my ($edid, $verbose) = @_;
455
456  print "Name: $edid->{monitor_name}\n" if $edid->{monitor_name};
457  print "EISA ID: $edid->{EISA_ID}\n" if $edid->{EISA_ID};
458  printf "Screen size: %.1f cm x %.1f cm (%3.2f inches%s)\n",
459  $edid->{max_size_horizontal},
460  $edid->{max_size_vertical},
461  $edid->{diagonal_size},
462  $edid->{ratio_name} ? sprintf(", aspect ratio %s = %.2f", $edid->{ratio_name}, $edid->{ratio}) :
463  $edid->{ratio} ? sprintf(", aspect ratio %.2f", $edid->{ratio}) : '';
464
465  print "Gamma: ", $edid->{gamma} / 100 + 1, "\n";
466  printf "%s signal\n", $edid->{video_input_definition}{digital} ? 'Digital' : 'Analog';
467
468  if ($verbose) {
469    foreach (@{$edid->{established_timings} || []}) {
470      print "Standard resolution: $_->{X}x$_->{Y} @ $_->{vfreq} Hz (established timing)\n" if !$_->{interlace};
471    }
472    foreach (@{$edid->{standard_timings} || []}) {
473      print "Standard resolution: $_->{X}x$_->{Y} @ $_->{vfreq} Hz, ratio $_->{ratio}",
474      $edid->{ratio_name} && index($edid->{ratio_name}, $_->{ratio}) == -1 ? ' (!)' : '',
475      "\n";
476    }
477  }
478
479  if ($edid->{monitor_range}) {
480    printf "Max video bandwidth: %u MHz\n", $edid->{monitor_range}{pixel_clock_max} if $edid->{monitor_range}{pixel_clock_max};
481    print "\n";
482    printf "\tHorizSync %u-%u\n", $edid->{monitor_range}{horizontal_min}, $edid->{monitor_range}{horizontal_max};
483    printf "\tVertRefresh %u-%u\n", $edid->{monitor_range}{vertical_min}, $edid->{monitor_range}{vertical_max};
484  }
485
486  foreach my $h (@{$edid->{detailed_timings}}) {
487    print "\n";
488    print "\t", $h->{ModeLine_comment}, $h->{bad_ratio} ? ' (bad ratio)' : '', "\n";
489    print "\tModeLine ", $h->{ModeLine}, "\n"; 
490  }
491}
492
493sub _getManifacturerFromCode {
494  my $code = shift;
495  my $h = {
496    "ACR" => "Acer America Corp.",
497    "ACT" => "Targa",
498    "ADI" => "ADI Corporation http://www.adi.com.tw",
499    "AOC" => "AOC International (USA) Ltd.",
500    "API" => "Acer America Corp.",
501    "APP" => "Apple Computer, Inc.",
502    "ART" => "ArtMedia",
503    "AST" => "AST Research",
504    "CPL" => "Compal Electronics, Inc. / ALFA",
505    "CPQ" => "COMPAQ Computer Corp.",
506    "CTX" => "CTX - Chuntex Electronic Co.",
507    "DEC" => "Digital Equipment Corporation",
508    "DEL" => "Dell Computer Corp.",
509    "DPC" => "Delta Electronics, Inc.",
510    "DWE" => "Daewoo Telecom Ltd",
511    "ECS" => "ELITEGROUP Computer Systems",
512    "EIZ" => "EIZO",
513    "EPI" => "Envision Peripherals, Inc.",
514    "FCM" => "Funai Electric Company of Taiwan",
515    "FUS" => "Fujitsu Siemens",
516    "GSM" => "LG Electronics Inc. (GoldStar Technology, Inc.)",
517    "GWY" => "Gateway 2000",
518    "HEI" => "Hyundai Electronics Industries Co., Ltd.",
519    "HIT" => "Hitachi",
520    "HSD" => "Hanns.G",
521    "HSL" => "Hansol Electronics",
522    "HTC" => "Hitachi Ltd. / Nissei Sangyo America Ltd.",
523    "HWP" => "Hewlett Packard",
524    "IBM" => "IBM PC Company",
525    "ICL" => "Fujitsu ICL",
526    "IVM" => "Idek Iiyama North America, Inc.",
527    "KFC" => "KFC Computek",
528    "LEN" => "Lenovo",
529    "LGD" => "LG Display",
530    "LKM" => "ADLAS / AZALEA",
531    "LNK" => "LINK Technologies, Inc.",
532    "LTN" => "Lite-On",
533    "MAG" => "MAG InnoVision",
534    "MAX" => "Maxdata Computer GmbH",
535    "MEI" => "Panasonic Comm. & Systems Co.",
536    "MEL" => "Mitsubishi Electronics",
537    "MIR" => "miro Computer Products AG",
538    "MTC" => "MITAC",
539    "NAN" => "NANAO",
540    "NEC" => "NEC Technologies, Inc.",
541    "NOK" => "Nokia",
542    "OQI" => "OPTIQUEST",
543    "PBN" => "Packard Bell",
544    "PGS" => "Princeton Graphic Systems",
545    "PHL" => "Philips Consumer Electronics Co.",
546    "REL" => "Relisys",
547    "SAM" => "Samsung",
548    "SMI" => "Smile",
549    "SMC" => "Samtron",
550    "SNI" => "Siemens Nixdorf",
551    "SNY" => "Sony Corporation",
552    "SPT" => "Sceptre",
553    "SRC" => "Shamrock Technology",
554    "STN" => "Samtron",
555    "STP" => "Sceptre",
556    "TAT" => "Tatung Co. of America, Inc.",
557    "TRL" => "Royal Information Company",
558    "TSB" => "Toshiba, Inc.",
559    "UNM" => "Unisys Corporation",
560    "VSC" => "ViewSonic Corporation",
561    "WTC" => "Wen Technology",
562    "ZCM" => "Zenith Data Systems",
563    "___" => "Targa" };
564
565  return $h->{$code} if (exists ($h->{$code}) && $h->{$code});
566  return "Unknown manufacturer code ".$code;
567}
568
569sub sqr { $_[0] * $_[0] }
570sub round { int($_[0] + 0.5) }
571sub group_by2 {
572  my @l;
573  for (my $i = 0; $i < @_; $i += 2) {
574    push @l, [ $_[$i], $_[$i+1] ];
575  }
576  @l;
577}
578
579
580sub run {
581  my $params = shift;
582  my $common = $params->{common};
583  my $logger = $params->{logger};
584
585  my $raw_perl = 1;
586  my $verbose;
587  my $MonitorsDB;
588  my $base64;
589  my $uuencode;
590 
591  my $raw_edid = getEdid();
592
593  return unless $raw_edid;
594
595  length($raw_edid) == 128 || length($raw_edid) == 256 or
596  $logger->debug("incorrect lenght: bad edid");
597
598  my $edid = parse_edid($raw_edid);
599  if (my $err = check_parsed_edid($edid)) {
600    $logger->debug("check failed: bad edid: $err");
601  }
602
603  my $caption = $edid->{monitor_name};
604  my $description = $edid->{week}."/".$edid->{year};
605  my $manufacturer = _getManifacturerFromCode($edid->{manufacturer_name});
606  my $serial = $edid->{serial_number2}[0];
607
608  eval "use MIME::Base64;";
609  $base64 = encode_base64($raw_edid) if !$@;
610  if (can_run("uuencode")) {
611    chomp($uuencode = `echo $raw_edid|uuencode -`);
612    if (!$base64) {
613      chomp($base64 = `echo $raw_edid|uuencode -m -`);
614    }
615  }
616  $common->addMonitors ({
617
618      BASE64 => $base64,
619      CAPTION => $caption,
620      DESCRIPTION => $description,
621      MANUFACTURER => $manufacturer,
622      SERIAL => $serial,
623      UUENCODE => $uuencode,
624
625    });
626}
6271;
628
Note: See TracBrowser for help on using the repository browser.